Fonction Google Sheets : REGEXEXTRACT

La fonction REGEXEXTRACT extrait une ou plusieurs parties d'un texte en utilisant des expressions régulières.

Utilisation :

=REGEXEXTRACT(texte; expression_régulière)

Si vous ne savez pas ce qu'est une expression régulière ou si vous ne savez pas comment en écrire une, commencez par bien lire le tutoriel complet qui accompage la fonction REGEXMATCH avant de poursuivre (ceci afin de vous éviter quelques maux de tête à la lecture de certaines regex de cette page).

Extraire le premier mot trouvé

La fonction REGEXEXTRACT retourne ici le premier mot trouvé parmi les 2 possibilités ("amusant" ou "terrifiant") :

=REGEXEXTRACT(A2;"amusant|terrifiant")

Extraire une référence

La fonction REGEXEXTRACT retourne cette fois-ci la partie du numéro de référence correspondant à l'expression "[A-Z]\d{2}" (soit une lettre en majuscule suivie de 2 chiffres) :

=REGEXEXTRACT(A2;"[A-Z]\d{2}")

google sheets fonction regexextract extraire reference

Extraire un nombre

La regex "\d*" correspond à "tous les chiffres en quantité illimitée", autrement dit, la fonction va extraire ici tous les chiffres jusqu'à tomber sur un caractère qui n'en est pas un :

=REGEXEXTRACT(A2;"\d*")

google sheets fonction regexextract numeros

Extraire à la fin

Pour extraire les chiffres à la fin du texte cette fois-ci, ajouez un "$" à la fin de la regex :

=REGEXEXTRACT(A2;"\d*$")

google sheets fonction regexextract numeros fin

Extraire plusieurs parties

Pour extraire les différents groupes de chiffres, ajoutez des parenthèses sur chaque partie du texte à extraire :

=REGEXEXTRACT(A2;"(\d*)-?(\d*)-?(\d*)-?(\d*)")

google sheets fonction regexextract extraire plusieurs chaines

Extraire au milieu

Pour extraire par exemple le second groupe de chiffres, la regex est la suivante :

=REGEXEXTRACT(A2;"(?:(\d*)-?){2}")

L'ajout de "?:" après la première parenthèse indique qu'elle n'est pas capturante (elle ne renverra donc aucune valeur). Il ne reste alors plus qu'une paire de parenthèses (donc une seule valeur renvoyée) et un quantificateur à 2 :

google sheets fonction regexextract parentheses non capturantes

Si vous avez besoin d'extraire une valeur d'une cellule, vous pouvez essayer d'utiliser le générateur de formules d'extraction du site.