Cours Google Sheets : les graphiques Sparkline

Un graphique Sparkline est un graphique miniature inséré directement dans une cellule.

Dans Google Sheets, le graphique Sparkline est disponible sous forme de fonction.


Insérer un graphique Sparkline

Pour créer un graphique Sparkline, insérez la fonction SPARKLINE et sélectionnez les données sources :

google-sheets-insertion-graphique-sparkline - sparkline

Le graphique est alors inséré dans la cellule et vous donne un aperçu visuel des différents montants à sa gauche :

google-sheets-graphique-sparkline - sparkline

Puisqu'il s'agit d'une fonction, vous pouvez la recopier :

google-sheets-graphique-sparkline-recopie - sparkline

Pour obtenir :

google-sheets-graphiques-sparkline - sparkline

Personnaliser un graphique Sparkline

Pour obtenir une version personnalisée du graphique Sparkline, il faut entrer un ou plusieurs paramètres (séparés par des ;) entre {} en 2e argument.

Par exemple : =SPARKLINE(B2:G2;{"charttype"\"line"})

Important : si votre séparateur de décimales n'est pas la virgule et que la fonction génère une erreur, remplacez les \ par des , dans toutes les formules.

Pour obtenir : =SPARKLINE(B2:G2;{"charttype","line"})

Les types de graphiques Sparkline

Le graphique à courbes (par défaut) : =SPARKLINE(B2:G2;{"charttype"\"line"})

google-sheets-graphique-sparkline-line - sparkline

Le graphique à barres empilées : =SPARKLINE(B2:G2;{"charttype"\"bar"})

google-sheets-graphique-sparkline-bar - sparkline

Le graphique à colonnes : =SPARKLINE(B2:G2;{"charttype"\"column"})

google-sheets-graphique-sparkline-column - sparkline

Le graphique positif ou négatif : =SPARKLINE(B2:G2;{"charttype"\"winloss"})

google-sheets-graphique-sparkline-winloss - sparkline

Couleur des graphiques Sparkline

Le graphique à colonnes en vert : =SPARKLINE(B2:G2;{"charttype"\"column";"color"\"green"})

google-sheets-graphique-sparkline-column-green - sparkline

Vous pouvez entrer une couleur par son nom en anglais (green) ou par sa valeur hexadécimale (#008000).

Le graphique à courbes en rose : =SPARKLINE(B2:G2;{"charttype"\"line";"color"\"#ff009a"})

google-sheets-graphique-sparkline-line-rose - sparkline

Il n'est ici pas nécessaire de préciser le type =SPARKLINE(B2:G2;{"color"\"#ff009a"}) puisqu'il s'agit du type de graphique par défaut.

Couleur du minimum et du maximum

Le graphique à colonnes avec le minimum en rouge et le maximum en vert :

=SPARKLINE(B2:G2;{"charttype"\"column";"lowcolor"\"red";"highcolor"\"#00b100"})

google-sheets-graphique-sparkline-column-green-red - sparkline

Epaisseur de ligne

Le graphique à courbes avec une épaisseur de 3 :

=SPARKLINE(B2:G2;{"color"\"#00b1ff";"linewidth"\3})

google-sheets-graphique-sparkline-ligne-epaisse - sparkline

Y minimum et maximum

Le graphique à colonnes une plage Y définie :

=SPARKLINE(B2:G2;{"charttype"\"column";"ymin"\20000;"ymax"\80000})

google-sheets-sparkline-min-max - sparkline

Graphique à barres avec maximum

Le graphique à barres avec un maximum défini à 400000 :

=SPARKLINE(B2:G2;{"charttype"\"bar";"max"\400000})

google-sheets-sparkline-bar-max - sparkline

Pour donner l'apparence d'une somme, utilisez une couleur unique :

=SPARKLINE(B2:G2;{"charttype"\"bar";"max"\400000;"color1"\"#65cd2c";"color2"\"#65cd2c"})

google-sheets-sparkline-bar-somme - sparkline

La version avec une seule valeur et un maximum défini à 60000 :

=SPARKLINE(B2;{"charttype"\"bar";"max"\60000})

google-sheets-graphique-sparkline-barre - sparkline

Il est également possible d'utiliser des fonctions pour définir les valeurs des paramètres de SPARKLINE. Par exemple, le maximum est ici calculé à l'aide d'une fonction (puis arrondi pour obtenir un nombre entier) :

=SPARKLINE(B2;{"charttype"\"bar";"max"\ARRONDI(MAX($B$2:$B$4))})

google-sheets-graphique-sparkline-max-fonction - sparkline

Plus de couleurs

Une liste de 729 couleurs utilisables avec SPARKLINE est disponible ici : liste de couleurs

Plus de paramètres

Il existe encore bien d'autres paramètres pour personnaliser vos graphiques Sparkline.

Cette liste est disponible sur le site de Google : https://support.google.com/docs/answer/3093289